**FORCE-TIME CHARACTERISTICS OF THE COUNTERMOVEMENT JUMP: ANALYZING THE CURVE IN EXCEL**

**AUTHORS:**

Shyam Chavda – MSc, PGCHE, CSCS, ACSS, CES1, Tom Bromley - MSc1, Paul Jarvis –

MSc1 , Steve Williams – MSc, PGCHE1, Chris Bishop –MSc, PGCHE1, Anthony N Turner –

PhD, CSCS\*D1, Jason P Lake – PhD2 and Peter D Mundy – PhD, CSCS, ASCC3.

**INSTITUTION:**

1. London Sports Institute, Middlesex University, Allianz Park, Greenlands Lane, NW4 1RL

2. Chichester Institute of Sport, University of Chichester, College Lane, Chichester, PO19

6PE.

3. Coventry University, Priory Street, Coventry, United Kingdom, CV1 5FB

**CORRESPONDENCE:**

**Email:** s.chavda@mdx.ac.uk

**Tel No:** (+44)20 8411 2854

**Address:** As per above

Shyam Chavda is strength and conditioning coach and technical tutor at the London Sport

Institute, Middlesex University. He is the lead coach for the Middlesex University weightlifting club and a regional coach for British Weightlifting.

Tom Bromley is a first team sports scientist for Milton Keynes Dons football club, reading

MSc in strength and conditioning at Middlesex University.

Paul Jarvis is a strength and conditioning coach and associate sports science lecturer at the

London Sport Institute, Middlesex University.

Steve Williams is a lecturer in biomechanics at the London Sport Institute.

Chris Bishop is a strength and conditioning coach at the London Sport Institute, Middlesex

University, where he is also the programme leader for the MSc in Strength and Conditioning.

Anthony N Turner is the director of postgraduate programmes in sport at the London Sport

Institute, Middlesex University.

Jason Lake is a Reader in Sport and Exercise Biomechanics and program leader of the MSc in

Strength and Conditioning in the Department of Sport and Exercise Science at the University

of Chichester.

Peter Mundy is a lecturer in biomechanics and course director in strength and conditioning at

Coventry university.

**ABSTRACT**

Increased popularity in the utilization of force plates to measure countermovement jumps (cmjs) for performance monitoring warrants the need for strength and conditioning coaches and sport scientists to better under-stand its force-time characteristics and the calculation of its associated variables. this article aims to provide information on how to understand and analyze the force-time curve of cmjs in microsoft excel, thus providing practitioners an inexpensive and accessible alternative to readily avail-able software on the market.

**INTRODUCTION**

The countermovement jump (CMJ) is a highly-used movement to help coaches determine performance changes (1) and fatigue levels (4,15). Typically jumps are measured using contact mats, linear position transducers (LPTs), photoelectric cells, or smartphone applications, and their associated software. Although these technologies are reliable, cost significantly less than force plates, provide instantaneous results, and are portable, they can constrain testing metrics to absolute outcome measures such as jump height, lower-body power (5,15), and concentric force and velocity through theoretical integration (16). Although these variables are highly relevant to sports performance and perhaps readiness to train, valuable information related to vertical ground reaction force (VGRF) cannot be measured, which can provide details as to how these outcome measures are achieved and an insight into alter-native variables unavailable through the aforementioned.

Recently, there has been an increased interest in the use of force plates to collect CMJ variables, potentially because of their increase in affordability and accessibility. The caveat to collecting CMJ variables from a force plate is that the practitioner needs a way to process the data, and this may incur additional costs for automated software. An alternative is to process and analyze raw force plate data using Microsoft Excel (or other spreadsheet software) to analyze variables that not only relate to absolute outcome measures but also information relating to the jumper’s force capabilities, such as impulse during specific phases of the jump. There-fore, the aim of this study is to assist practitioners in understanding the key CMJ phases by explaining how to define them and calculate them using Microsoft Excel.

**UNDERSTANDING THE FORCE-TIME CURVE**

Before analyzing any data in Microsoft Excel, it is important for coaches and sports scientists to understand the CMJ force-time curve. This will make it easier to understand the key phases from which variables are derived. Figure 1 depicts a typical CMJ force-time curve plotted with force on the “y” axis and velocity on the “x” axis. Before the beginning of the movement, there is a steady stance, or quiet standing, period (“bodyweight” between 0 and “A” in Figure 1; to be discussed later in the article). Once the movement be-gins, impulse (area under the force curve relating to force and time) drops below the bodyweight baseline (Figure 1A and 1B) (11). This is known as the “unweighting phase,” where the athlete begins to flex the knees and hips, and drops their center of mass (COM) causing a downward acceleration, with the end of this phase defined by the lowest velocity before take-off (Figure 1C). To over-come this, the athlete now activates their leg musculature and thus, creating an impulse above baseline (bodyweight), although at this point, they are still moving downward. It is when the athlete reaches zero velocity (Figure 1D) or when the impulse above baseline (Figure 1B–D) is equal to the impulse created during the unweighting phase (Figure 1A and 1B), the jumper achieves his/her lowest countermovement position. This is termed as the “braking phase,” which is directly followed by the “propulsive phase” exhibited by a rise in peak force (Figure 1D and 1E). The reduction in force after peak force to the point of take-off is denoted in Figure 1G where the jumper’s feet leaves the floor, so that their COM is now higher than it was at the beginning of the jump. At this point, the athlete’s COM has reached zero acceleration and their velocity has peaked just before “flight” (Figure 1F). Once in flight, his/her COM begins to decelerate due to the effect of gravity.

At this point, the jumper is experiencing zero velocity and is moving neither up nor down, thus depicting the apex of the jump or peak displacement (Figure 1H). The instance of landing occurs when force begins to increase on contact (Figure 1I), with peak landing force depicted as the largest spike after landing (Figure 1J).

**COLLECTING AND ANALYZING THE DATA**

***SETTING UP THE TEMPLATE AND ACCOUNTING FOR SAMPLING FREQUENCY***

The template layout depicted in Figure 2 is a simplistic layout to help define key information that dictates the different phases of the jump. Hereafter, the article will refer to cells relating to the template, although any combination of the template can be created to fit the reader’s requirements.

First, the sampling frequency needs to be converted from hertz (Hz) to time (s). The sampling effectively tells us how many data points are collected in 1 second and will be needed when calculating bodyweight, impulse, velocity, and displacement. The determination of the sampling frequency will be dependent on the force plate’s capabilities, with the thought that higher frequencies will capture more accurate values (i.e., more data points per second) (7); however, practitioners may consider going as low as 200 Hz because values relating to jump performance measures have marginal differences (21.8 to 1.31%) when compared with frequencies as high as 500 Hz (7)

Next to the “Sample Frequency” cell (Figure 2, cell K1) insert the frequency at which the jump was collected. Below this cell, the Time point can be defined inserting equation a (Table 1) next to the “Time point (s)” cell (Figure 2, K2). The Time point should now auto-calculate when a sampling frequency is entered. As an example, a Sample Frequency of 1,000 Hz will give a data point every 0.001 second.

***PROCESSING THE COLUMNS***

Before extracting jump phase information, the authors recommend setting up the equations b–g (Table 1) in columns C–H. These columns will pro-cess acceleration, velocity, displacement, and power during each Time point and will play a fundamental role in defining the jump phases and extracting variables of interest. Initially “Net Force (N)” needs to be calculated in column C by subtracting the jumper’s bodyweight away from the force pasted in column B. At this point, the value that comes up will be the same as the absolute force because the jumper’s bodyweight has not yet been calculated (this is described in the defining bodyweight section). From the net force column, the “Impulse (N·s)” can be calculated in column D using equation c (Table 1). This is the integration of force and time, and is commonly referred to as the area under the curve. The impulse is calculated as an average of the net force generated over 2 Time points multiplied by time and will help provide information on the total amount of force generated during specific phases of the jump. Previous literature has shown that there are differences in curve characteristics and impulse between skilled and unskilled jumpers (6) as well as strong and weak jumpers (2). More skilled and stronger jumpers are shown to create a greater impulse through exerting higher levels of force over a shorter period of time during the propulsive phase as indicated by an increase in jump velocity and rate of force development (3). This means that they are able to accelerate their mass faster, create a greater take-off velocity, and thus jump higher. Second, shallower countermovements (i. e., end of unweighting to end of braking phase) have also been reported to decrease after strength and power interventions (1,5), suggesting improved ability to use the stretch-shortening cycle.

Therefore, based on the above, using eccentric and concentric impulse as a variable to monitor performance can provide coaches with information about how outcome measures are achieved, and potentially indicate the nature of change elicited by a training intervention or fatigue. Using the principles of physics, the following equations can be used to calculate columns E–H, respectively:

Acceleration $a=\frac{F}{m}$ (eq 1)

Velocity $V=u+at$ (eq 2)

 Displacement $s= \frac{1}{2}\left(v-u\right)t $ (eq 3)

Power $P=FV$ (eq 4)

Where; a = acceleration, F = force, m = mass, V = final velocity, u = initial velocity, t = time, s = displacement, and P = power.

The calculation of acceleration con-ducted in column E (Table 1, equation d), simply divides absolute force by the athlete’s mass. Because the athlete’s mass has not yet been calculated from the baseline (this is described in the defining bodyweight section), an error, #DIV/0!, may appear in the cell, which will change once mass is defined. Because acceleration has been calculated, it can be integrated to derive velocity using equation 2 as shown above. This is achieved by adding initial velocity to the sum of acceleration multiplied by time (Table 1, equation e). The calculation of velocity plays a significant role in helping to define where the specific phases of the jump occur and therefore plays a pivotal role when extracting variables of interest later. We can then integrate the velocity to obtain displacement, which will be used to help define the landing at a later phase. This is achieved by multiplying 0.5 by the sum of final velocity, minus initial velocity and then multiplying this by the Time point. The Time point in this case will be dependent on the frequency the jump was collected (Table 1, equation f ). Power generated through the jump can also be easily calculated by multiplying force and velocity (Table 1, equation g), which allows us to extract power related variables. Because power is a sought-after CMJ metric, this is deemed an important performance factor in time-constrained tasks (13). Peak power, as the names states, is the peak (highest value) of work done within the jump. Much like peak force, this value represents one instantaneous moment in time, equivalent to 1 Hz, and there-fore only presents a small portion of the jump. Arguably average power presents a greater portion of the jump and may be able to help coaches decipher what changes have occurred, the jump strategies used, and at which phase, which may be particularly useful where performance is time constrained (i.e., must occur quickly). All equations need to be applied to all rows up to the end of your force and time data. This can easily be performed by highlighting the cells and double clicking the bottom right corner.

***STEADY STANCE AND DEFINING BODYWEIGHT***

Before phase detection, it is important that practitioners understand the value and methodological rigor required to collect CMJ force-time data. To collect reliable and easy-to-analyze data, the plate must be zeroed before the athlete stands on it. Once this is performed, the athlete must adopt the ready position (hands on hips and feet preferred width apart) and stand motionless on the plate for at least 1 second so that bodyweight can be obtained (14). The importance of this is to quantify the jumper’s bodyweight by averaging the motionless period, which in turn will enable the detection of the initiation of the jump at a later stage.

Once data has been collected, check using the data acquisition software to see whether there is a quiet stance of at least 1 second before movement. If large levels of fluctuation are identified in the steady stance, the authors suggest a new trial to be recorded. When happy with the acquired data, transfer it to a text file and copy and paste the time and raw data of the VGRF into cells A2 and B2 of the spreadsheet, respectively. It is suggested to graph these data using a scatter plot with smooth lines to visualize the force-time curve. This helps contextualize the equations that need to be entered into Excel and ensures that data are obtained from the phases of interest.

Next to “Baseline Start” (Figure 2, cell K3), insert the cell number of where the baseline should start from. Under this, insert equation h (Table 1) which will end the baseline 1 second after the defined start. Remember, this period must have a flat line with minimal fluctuations and be as close to the beginning of the jump as possible (i.e., from when force starts to decrease). It is now possible to find the average force between the 2 baseline markers to compute the athlete’s bodyweight. This is performed by entering equation i (Table 1) next to the “Bodyweight (N)” cell and can then be converted into mass (kg) in the “Mass (kg)” cell by simply dividing the value by gravitational force (9.81) (Table 1, equation j).

***DEFINING THE START***

Defining the start of the jump dictates the accuracy of the variables derived from the CMJ; therefore, using a robust methodology is imperative. Unfortunately, there is no agreed method for determining the initiation of the jump, with previous research defining the initiation using manual inspection, predetermined thresholds based on percentage of bodyweight (10) and 5 SD of bodyweight (14).

In brief, the manual inspection method can be time consuming and is not a viable option for coaches with time constraints, and of course lends itself to human error, and although reliable, the predetermined threshold could very well exclude signals relating to the jump. Identifying the initiation of the jump as the first force value less than 5 SD of bodyweight has been shown to reduce the probability of identifying the incorrect start point (14). To achieve this, bodyweight minus 5 SD needs to be obtained in Excel. In the cell to the right of the “BW - 5 SD Value (N),” insert equation k (Table 1). This will effectively subtract 5 SD from body-weight and identify the start of the jump. After this, equations l and m (Table 1) can be used to calculate the row number and associated time point at which “BW - 5 SD Value (N)” occurs, respectively. It is important to understand that at this point, movement has occurred, and the jump has already started; thus, velocity will not be zero. In turn, this can reduce the accuracy of the velocity calculations and affect phase detection and outcome measures such as jump height and power. To calculate an appropriate point at which velocity is likely to be zero, Owens et al. (14), suggested that the point of integration (point when VGRF after signal to jump exceeds BW ± 5 SD) is taken -30 ms from the initiation of the jump (-30 ms from bodyweight - 5 SD). This is out-lined in Table 1 equation n–p, and will therefore start calculating velocity, dis-placement, and power -30 ms from the defined start threshold of BW-5 SD, with greater confidence that velocity is at 0.

***FINDING PEAK FORCE***

The peak force of the jump refers to the largest force generated before take-off. To compute the end of the un-weighting phase and braking phase, respectively, knowing the row of peak force will act as a reference point, therefore shortening the number of equations required. The peak force row, time, and value can be calculated using equations q–s (Table 1), using a combination of INDEX and MATCH functions. Readers may notice that the value computed in fact relates to the peak landing force. This is due to having not yet calculated the take-off value, of which the “Peak Force Row” equation uses to tell Excel to look for the peak up to the take-off.

***FINDING THE END OF THE UNWEIGHTING PHASE***

The end of the unweighting phase is defined as when VGRF reaches a value equal to that of the athlete’s body-weight (Figure 1B). Because the start threshold of the jump may not exist, it can be difficult to ask Excel to find the same or similar value to define this phase. A good alternative is to use the lowest velocity value (Table 1, equation t), which marks the end of the negative acceleration associated with this phase. Once obtained, the Time point at which this occurs, along with its associated value can be obtained (Table 1, equation u and v, respectively).

***FINDING THE END OF THE BRAKING PHASE***

The end of the braking phase marks the athlete switching from a predominantly eccentric motion to a predominantly concentric, propulsive motion. This is dictated by velocity reaching 0 and is calculated using equation w (Table 1). Once again, an INDEX function can be used to define the Time point and value of the braking phase (Table 1, equation x and y, respectively). Because velocity starts at 0 and goes into negative values, it is advised that the reader inserts 0.01 as the MATCH number in equation w (8). This will enable this function to search for the first positive value after 0.

***PEAK DISPLACEMENT***

Peak displacement will provide information on the COM such as its peak. This occurs when velocity reaches zero and will help to later define the landing point within Excel, and thus peak landing force (Table 1, equations z and aa).

***TAKE-OFF AND LANDING***

Much like defining the start of a jump, many methods have been used to identify take-off. These include: taking the value greater than the peak residual force across a 0.3-second period during the flight phase (12), 5 SD during the flight phase across a 0.3-second period (9), and identifying the first VGRF value under a defined threshold, such as 10 N (13). Because we need to account for any variability produced by noise of either the individual or the force plate the authors suggest using 5 SD of 300-ms flight force, thus reducing the misidentification of take-off. To achieve this, Excel must look for a value less than 10 N in the force array by inserting equation ab (Table 1). It should be noted that Excel may not find exactly 10 N; therefore, the -1 in the equation will look for the smallest value in the array selected (in this case, the force column) that is equal to or greater than 10 N. Once the take-off row is defined, the time and value of take-off can be computed using equations ac and ad, respectively (Table 1).

Once this has been performed, the landing row, time, and force value can be calculated (Table 1, equations ae, af, and ag, respectively). This is calculated using a match function looking for a value greater than 10 N between peak displacement and peak landing force. Now that take-off and landing have been defined, a threshold using 5 SD needs to be calculated for both phases. Previous literature (9,12) have used an arbitrary unit of 300 ms from take-off to calculate the 5 SD thresh-olds because a meaningful change in the force can be detected that best rep-resents the take-off and that falls out-side the noise of the force plate. Second, 300 ms is a long enough time in that it measures a substantial amount of the flight time, given that most individuals will have a flight time greater than 300 ms. When inserting the equations ah and aj (Table 1), readers should be cautioned that the value 300 relates to 300 ms based off of the 1,000 Hz the example data were collected at. Therefore, should the reader collect jumps at a different frequency, then it is recommended that this figure is altered so it represent 300 ms (i.e., 500 Hz = 150). On completion, the time at which take-off and landing 5 SD occurs can be calculated using equations ak and al (Table 1), respectively.

**SETTING UP POINTS OF INTEREST**

Now that the spreadsheet functions can detect the start and end of key phases, it is useful to present this in a graphical format (Figure 3). The authors suggest this for 2 reasons; (a) it allows coaches to see whether the phases are in the correct place and allows for any corrections to be made in the template if the points are incorrect relative to Figure 1. First and foremost, a scatter plot graph needs to be inserted by selecting column B, going to the “Insert” tab and selecting “scatter with smooth lines” under “charts.” Next, the point of interest (POI) can be inserted, which include but are not limited to; Start, end of un-weighting, end of braking, and take-off. This requires the use of an offset function, which will help define the specific POI in the force-time curve. In cell K9, next to “BW - 5SD Row”, type the following formula; = OFFSET(B2, K9,0), where B2 is the start of the Fz column, K9 is the start of row cell number, and 0 is the column. This needs to be repeated for each POI replacing K9 with its respective row cell number (i.e., end of unweighting is K15). From here, the POI can be added onto the graph by right clicking the graph and selecting “Select data..” In the pop up, select “Add” and select the series name, X value (row number), and Y value (offset value) for each POI. Once complete, some editing is required to highlight these points. This is achieved simply by right clicking the chart and selecting “Change chart type.,” selecting “Combo,” and altering the Fz series to “Scatter with smooth lines” and all series relating to the POI as “Scatter.” Note that the “secondary axis” box for the POI should be unchecked. The POI colors can be edited to the reader’s requirements. To add a key, click on the graph and go to “quick layout” found under the “Design” tab and select the most convenient layout.

**TYPICAL VS ALTERNATIVE VARIABLES**

Now that the template is set up, it is possible to extract variables of interest. A range of variables can be obtained from CMJ VGRF, and are generally categorized as “typical” and “alternative,” as outlined in Table 2 (4,5). Typical variables refer to commonly used outcome measures that relate to absolute values for the concentric portion of the jump (i.e., jump height and peak power). Although these variables are easy to obtain, they may overlook key components within the jump, which may help better explain altered jump strategies during fatigue or changes in temporal force-time characteristics after an intervention. For example, the shape of the curve has been shown to change after a periodized program of strength and power training (5), as well as power-only interventions (1). The outcome elicited a shallower counter-movement, steeper rise in force during the braking phase, and a higher peak force, with concurrent increases in peak power and take-off velocity, and consequently, jump height. However, Cormie et al. (1), concluded that peak performance variables, such as peak power and peak force, offer little insight into how adaptations have occurred; thus, examining changes in temporal force and power may help coaches more clearly understand the type of change elicited from an intervention. It is for this reason that alternative variables have gained attention because they may pro-vide a better insight into neuromuscular-related changes relating to contraction times (e.g., eccentric contraction time and concentric contraction time) and force-velocity relationships (e.g., force at zero velocity and force-velocity area under curve). Furthermore, given this greater insight into neuromuscular function, sensitivity to change can be explored in greater depth, thus allowing coaches to understand the level and magnitude of changes occurring, and more specifically, at what phase they occur. The authors have presented Excel equations in Table 3 for some common variables that best describe jump characteristics.

**CONCLUSION**

It is important that coaches under-stand the constituent parts of the CMJ force-time curve before processing force-time data and extracting variables that may be used to detect performance changes or readiness to train. It can help coaches understand why it is important to calculate key variables, using the most robust and easy-to-apply methods, within the confines of day-to-day practice. Although peak values and averages relating to concentric data are highly reliable in field-based technologies, the underpinning determinants of these factors are influenced by a pre-stretch during the eccentric phase, of which the information is only obtainable through force-time data. Second, the time taken during each phase could also give coaches an insight into altered jump strategies. It should additionally be noted that with recent advances in technology, more portable and affordable force plates have become available, enabling coaches greater access to CMJ performance variables. Therefore, if viable, the authors suggest that force plates be used to assess CMJ. This is primarily due to their ability to not only detect and monitor underpinning changes in CMJ performance, but also to better inform inform training prescription and the understanding of training adaptation.

**REFERENCES**

1. Cormie P, McBride JM, and McCaulley GO. Power-time, force-time, and velocity-time curve analysis of the countermovement jump: Impact of training. *J Strength Cond* *Res* 23: 177–186, 2009.
2. Cormie P, McGuigan MR, and Newton RU. Influence of strength on magnitude and mechanisms of adaptation to power training. *Med Sci Sports Exe* 42: 1566– 1581, 2010.
3. Cormie P, McGuigan MR, and Newton RU. Adaptations in athletic performance after ballistic power versus strength training. *Med Sci Sports Exerc* 42: 1582–1598,2010.
4. Gathercole RJ, Sporer BC, Stellingwerff T, and Sleivert GG. Alternative countermovement jump analysis to quantify acute neuromuscular fatigue. *Int J Sports* *Physiol Perform* 10: 84–92, 2015.
5. Gathercole RJ, Stellingwerff T, and Sporer BC. Effect of acute fatigue and training adaptation on countermovement jump performance in elite snowboard cross athletes. *J Strength Cond Res* 29: 37–46, 2015.
6. Garhammer J and Gregor R. Propulsion forces as a function of intensity for weightlifting and vertical jumping. *J Appl* *Sport Sci Res* 6: 129–134, 1992.
7. Hori N, Newton RU, Kawamori N, McGuigan MR, Kraemer WJ, and Nosaka K. Reliability of performance measurements derived from ground reaction force data during countermovement jump and the influence of sampling frequency. *J Strength* *Cond Res* 23: 874–882, 2009.
8. McMahon JJ, Rej SJE, and Comfort P. Sex differences in countermovement jump phase characteristics. *Sports* 5: 1–11, 2017.
9. McMahon JJ, Murphy S, Rej SJE, and Comfort P. Countermovement jump phase characteristics of senior and academy rugby league players. *Int J Sports Physiol* *Perform* 0: 1–23, 2016.
10. Meylan CMP, Nosaka K, Green J, and Cronin JB. The effect of three different start thresholds on the kinematics and kinetics of a countermovement jump. *J Strength* *Cond Res* 25: 1164–1167, 2011.
11. Mizuguchi S, Sands WA, Wassinger CA, Lamont HS, and Stone MH. A new approach to determining net impulse and identification of its characteristics in countermovement jumping: Reliability and validity. *Sports Biomech* 14: 258–272, 2015.
12. Moir GL. Three different methods of calculating vertical jump height from force platform data in men and women. *Meas* *Phys Educ Exerc Sci* 12: 207–218, 2008.
13. Mundy PD, Lake JP, Carden PJC, Smith NA, and Lauder MA. Agreement between the force platform method and the combined method measurements of power output during the loaded countermovement jump. *Sports Biomech* 15: 23–35, 2016.
14. Owens NJ, Watkins J, Kilduff LP, Bevan HR, and Bennett MA. Development of a criterion method to determine peak mechanical power output in a countermovement jump. *J Strength Cond* *Res* 28: 1552–1558, 2014.
15. Roe GA, Darrall-Jones JD, Till K, and Jones B. Preseason changes in markers of lower body fatigue and performance in young professional rugby union players. *Eur J Sport Sci* 16: 981–988, 2016.
16. Samozino P, Morin JB, Hintzy F, and Belli A. Jumping ability: A theoretical integrative approach. *J Theor Biol* 264: 11–18, 2010.



**Figure 1.** Force- and velocity-time characteristics of a countermovement jump.



**Figure 2.** Excel template layout.

**Table 1**. Equations to calculate specific phases and variables pertaining to the CMJ in Microsoft Excel.

|  |  |  |
| --- | --- | --- |
| **Cell Name** | **Equation** | **Excel calculation** |
| Time | Copy and pasted from the raw data extracted from the force time curve. |  |
| Force (N) |  |
| a. Time point | = 1/ sample frequency | = 1/$K$1 |
| b. Net Force (N) | = Force – bodyweight  | =B2-$K$5 |
| c. Impulse\* | = (Average of current row and previous row of net force)) \* (1/sample frequency) | =(AVERAGE(C2:C3))\*(1/$K$1) |
| d. Acceleration | = Net force / mass  | = C2/$K$6 |
| e. Velocity\* | = IF(time point is >integration start time, SUM( velocity from above+(acceleration of row below\*time point)),”0.00”) | =IF(A3>$K$12,SUM(F2+(E3\*$K$2)),"0.00") |
| f. Displacement\* | = displacement from prior cell+(velocity of current row\*(1/sample frequency)) | =G2+(F3\*(1/$K$1)) |
| g. Power\* | =IF(time point is>integration start time, Fz\*integrated velocity,”0.00”) | =IF(A3>$K$12,B3\*F3,"0.00") |
| h. Baseline End (1 second) | = baseline start + sample frequency | = K3 + $K$1 |
| i. Bodyweight (N) | = AVERAGE (INDEX (force array, baseline start): INDEX (force array, baseline end)) | =AVERAGE(INDEX(B:B,K3):INDEX(B:B,K4)) |
| j. Mass (kg) | = bodyweight/gravity | =$K$5/9.81 |
| k. BW – 5SD Value (N) | = bodyweight-(5\*STDEV.P(INDEX (force array, baseline start):INDEX(force array, baseline end)))) | =K5-(5\*STDEV.P(INDEX(B:B,K3):INDEX(B:B,K4))) |
| l. BW – 5SD Row | = MATCH(BW-5SD value, force array, -1) | =MATCH(K8,B:B,-1) |
| m. BW – 5SD Time (s) | = INDEX(time array, start row) | =INDEX(A:A,K9) |
| n. Integration Start Time (s) | = BW – 5SD time (s) – 0.03 | =K10-0.03 |
| o. Integration Start Row  | =MATCH(Integration start time, time array, 1) | =MATCH(K12,A:A,1) |
| p. Integration Start Value (N) | =INDEX(net force array, integration start row) | =INDEX(B:B,K13) |
| q. Peak Force Row | =MATCH(MAX(INDEX( force array, first force cell):INDEX(force array, take off row cell)), force array, 0) | =MATCH(MAX(INDEX(B:B,B2):INDEX(B:B,K31)),B:B,0) |
| r. Peak Force Time (s) | =INDEX (time array, peak force row) | =INDEX(A:A,K16) |
| s. Peak force Value (N) | =INDEX (force array, peak force row) | =INDEX(B:B,K16) |
| t. End of Unweighting Row | =MATCH(MIN(INDEX(velocity array,1):INDEX(velocity array, peak force row)),INDEX(velocity array,1):INDEX(velocity array, peak force row),0) | =MATCH(MIN(INDEX(F:F,1):INDEX(F:F,K16)),INDEX(F:F,1):INDEX(F:F,K16),0) |
| u. End of Unweighting Time (s) | =INDEX(time array, end of unweighting row) | =INDEX(A:A,K20) |
| v. End of Unweighting Value (N) | =INDEX(force array, end of unweighting row) | =INDEX(B:B,K20) |
| w. End of Braking Row | =MATCH(0.01,INDEX(velocity array,1):INDEX(velocity array, peak force row),1) | =MATCH(0.01,INDEX(F:F,1):INDEX(F:F,K16),1) |
| x. End of Braking Time (s) | =INDEX(time array, end of braking row) | =INDEX(A:A,K24) |
| y. End of Braking Value (N) | =INDEX(force array, end of braking row) | =INDEX(B:B,K24) |
| z. Peak Displacement Row  | =MATCH(MAX(displacement array), displacement array,0) | =MATCH(MAX(G:G),G:G,0) |
| aa. Peak Displacement Time (s) | =INDEX(time array, peak displacement row) | =INDEX(A:A,K28) |
| ab. Take off Row | =MATCH(10,force array,-1) | =MATCH(10,B:B,-1) |
| ac. Take off Time (s) | =INDEX(time array, take off row) | =INDEX(A:A,K31) |
| ad. Take off Value (N) | =INDEX(force array, take off time) | =INDEX(B:B,K31) |
| ae. Landing Row | =MATCH(10,INDEX(force array,peak displacement row):INDEX(force array,(MATCH(MAX(force array),force array,0))),1)+peak displacement row | =MATCH(10,INDEX(B:B,K28):INDEX(B:B,(MATCH(MAX(B:B),B:B,0))),1)+K28 |
| af. Landing Time (s) | =INDEX(time array, landing row) | =INDEX(A:A,K35)  |
| ag. Landing Value (N) | =INDEX(force array, landing row) | =INDEX(B:B,K35) |
| ah. Take off/Landing Threshold 5SD (N) | =AVERAGE(INDEX(force array,(take off row+300)):INDEX(force array,(landing row-300)))+(5\*STDEV.P ( INDEX(force array,(take off row+300)):INDEX(force array,(landing row -300)))) | =AVERAGE(INDEX(B:B,(K31+300)):INDEX(B:B,(K35-300)))+(5\*STDEV.P(INDEX(B:B,(K31+300)):INDEX(B:B,(K35-300)))) |
| ai. Take Off Row 5SD | =MATCH(take off/landing threshold, force array, -1) | =MATCH(K39,B:B,-1) |
| aj. Landing Row 5SD | =MATCH(take off/landing threshold, INDEX(force array,(take off row 5SD+300)):INDEX(force array,(MATCH(MAX(force array),force array,0))),1)+(take off row 5SD+300) | =MATCH(K39,INDEX(B:B,(K40+300)):INDEX(B:B,(MATCH(MAX(B:B),B:B,0))),1)+(K40+300) |
| ak. Take Off Row 5SD Time (s) | =INDEX(time array, take off row 5SD) | =INDEX(A:A,K40) |
| al. Landing Row 5SD Time (s) | =INDEX(time array, landing row 5SD) | =INDEX(A:A,K41) |

\*next to the variables name means add the equation in the cell below, and input 0 in the cell above.



**Figure 3.** Graphical representation of VGRF data with points of interest. CMJ = countermovement jump; GRF = ground reaction force.

**Table** **2** – Typical and alternative variables previously obtained from ground reaction force data of CMJ’s.

|  |  |  |
| --- | --- | --- |
| **Typical variables** | **Unit** | **Variable Definitions** |
| Mean power | W | *peak concentric power / time of concentric phase.* |
| Maximum rate of power development | W/s | *largest power increase during a given time frame (ie, 30-ms)* |
| Time to peak power | s | *time it takes from the beginning of the propulsion phase to peak power* |
| Mean force | N | *peak concentric force / time of concentric phase* |
| Maximum rate of force development | N/s | *largest force increase during a given time frame (ie, 30-ms)* |
| Time to peak force | s | *time it takes from the beginning of the propulsion phase to peak force* |
| Relative net impulse | Ns/Kg | *total impulse / jumpers body mass* |
| Peak velocity | m/s | *fastest vertical speed of the centre of mass* |
| Minimum velocity | m/s | *slowest vertical speed of the centre of mass* |
| Velocity at peak power | m/s | *speed of the centre of mass at the point of peak power* |
| Flight time | s | *landing time – take off time* |
| Flight time: contraction time | - | *ratio of flight time to contraction time* |
| **Alternative Metrics** | **Unit** | **Metric Calculations and Definitions** |
| Force at 0 velocity | N | *force when velocity is zero (transition from eccentric to concentric)* |
| Force velocity – area under curve | N/ms2 | *area under the curve during eccentric phase* |
| Eccentric duration | s | *time of eccentric contraction during the countermovement* |
| Concentric duration | s | *time of concentric contraction during the jump* |
| Total duration | s | *eccentric + concentric duration* |
| Mean eccentric and concentric power over time | W · kg-1 · s-1 | *power during eccentric and concentric phase / total duration* |
| Reactive strength index modified | - | *jump height/time to take off* |

W = Watts, W/s = Watts per second, N = Newtons, Ns = Newtons per second, m/s = meters per second, s = seconds, Ns/Kg = Newtons per second, per kilogram, W · kg-1 · s-1 = Watts per kilo, per second.

**Table** **3** – Metrics obtainable from ground reaction force data of a CMJ.

|  |  |  |
| --- | --- | --- |
| **Cell Name** | **Equation** | **Excel Calculation** |
| a. Eccentric Impulse (Ns) | =SUM(INDEX(impulse array, end of unweighting row):INDEX(impulse array, end of braking row)) | =SUM(INDEX(D:D,K20):INDEX(D:D,K24)) |
| b. Concentric Impulse (Ns) | =SUM(INDEX(impulse array, end of braking row):INDEX(impulse array, take off row 5SD)) | =SUM(INDEX(D:D,K24):INDEX(D:D,K40)) |
| c. Duration of Eccentric Impulse (s) | = end of unweighting time – BW-5SD time | =K21-K10 |
| d. Duration of Concentric Impulse (s) | = end of braking time – take off 5SD time | =K32-K25 |
| e. Jump Height (m) | =SUM(MAX(velocity array)^2)/(2\*gravity) | =SUM(MAX(F:F)^2)/(2\*9.81) |
| f. Peak Force (N) | =peak force value - bodyweight | =K18-K5 |
| g. Peak Power (W) | =MAX(INDEX(power array, integration start row):INDEX(power array,take off row 5SD)) | =MAX(INDEX(H:H,K13):INDEX(H:H,K40)) |
| h. Eccentric Avg. Power (W) | =AVERAGE(INDEX(power array,integration start row):INDEX(power array,end of braking row)) | =AVERAGE(INDEX(H:H,K13):INDEX(H:H,K24)) |
| i. Concentric Avg. Power (W) | =AVERAGE(INDEX(power array,end of braking row):INDEX(power array,take off row 5SD)) | =AVERAGE(INDEX(H:H,K24):INDEX(H:H,K40)) |

W = Watts, N = Newtons, Ns = Newton per second, m = meters, s = seconds